| |
DL3KVR > TECHNIK 14.02.01 21:40l 154 Lines 6906 Bytes #-8142 (997) @ DL
BID : G8NYVADB0HRO
Read: DL5MDZ GUEST DG0TM OE7FMI
Subj: kabel.bas die 2.
Path: DB0ZKA<DB0KFB<DB0CZ<DB0GV<DB0BOX<DB0MRW<DB0SON<DB0ERF<DB0SAW<DB0SWM<
DB0MVP<DB0AGM<DF0HMB<DB0MAR<DB0HRO
Sent: 010212/2141z @:DB0HRO.#MVP.DEU.EU [Rostock] DP6.00 $:G8NYVADB0HRO
From: DL3KVR @ DB0HRO.#MVP.DEU.EU (Dietrich)
To: TECHNIK @ DL
X-Info: Einspielung ohne Passwortschutz
1 ' -überarbeitet, vertont und eingefärbt in GWbasic von DL3KVR im Januar 01
5 KEY OFF
6 PLAY "N25": PLAY "N30; L9": PLAY "N30; L9": PLAY "N30.....": PLAY "P5"
9 SCREEN 0: COLOR, 0: CLS
10 LOCATE 2, 8: COLOR 15, 6: LOCATE,8
11 PRINT" Dieses Basicprogramm dient der Bestimmung von Leistungsverlusten "
12 LOCATE,8
13 PRINT" einer Antennenanlage. "
14 LOCATE,8
15 PRINT" Das SWV an der Antenne läßt sich errechnen, wenn man das SWV am "
16 LOCATE,8
17 PRINT" Senderausgang kennt. "
18 LOCATE,8
19 PRINT" Leistungsverluste stehen im logarithmischen Verhältnis zur Lei- "
20 LOCATE,8
21 PRINT" tungslänge und werden allgemein in dB pro 100 m bei 30 MHz ange- "
22 LOCATE,8
23 PRINT" geben. "
24 LOCATE,8
25 PRINT" "
26 LOCATE,8
27 PRINT" Die Dämpfung A bei 30 MHz beträgt für RG-58 = 8.4 dB "
28 LOCATE,8
29 PRINT" für RG-213 = 3.6 dB "
30 LOCATE,8
31 PRINT" für H-100 = 2.3 dB "
32 LOCATE,8
33 PRINT" "
34 LOCATE,8
35 PRINT" Aus dieser Angabe läßt sich näherungsweise die Dämpfung für jede "
36 LOCATE,8
37 PRINT" Frequenz bis 1500 MHz ausrechnen. Über 1500 MHz hinaus ist mit "
38 LOCATE,8
39 PRINT" einer größeren Fehlerquote zu rechnen. "
40 LOCATE,8
41 PRINT" "
42 LOCATE,8
43 PRINT" Die Dämpfung Af pro 100 m für die Frequenz f berechnet sich wie "
44 LOCATE,8
45 PRINT" folgt: Af = A * 2.6^(log (f/30MHz) / 1.8) "
46 LOCATE,8
47 PRINT" "
48 LOCATE,8
49 PRINT" Für die Dämpfung D des Kabels mit der Länge l erhält man: "
50 LOCATE,8
51 PRINT" D = l * Af / 100 m "
52 LOCATE 25, 58: COLOR 4, 7: PRINT " WEITER ? (j/n) ";
53 X$ = INKEY$
54 IF X$ = "j" THEN GOTO 56
55 IF X$ = "n" THEN GOTO 410 ELSE 53
56 SCREEN 0: CLS: COLOR 15,6: LOCATE 4,8
57 LOCATE,8
58 PRINT" Aus der für die Sendefrequenz f abgeschätzten Dämpfung D kann nun "
59 LOCATE,8
60 PRINT" die Leistung P2 am Antennenfußpunkt berechnet werden: "
61 LOCATE,8
62 PRINT" D = 10 * log (P1/P2) daraus folgt: P2 = P1 / 10^ (D/10) "
63 LOCATE,8
64 PRINT" "
65 LOCATE,8
66 PRINT" Aus dem am Senderausgang gemessenen SWV kann die rückfließende "
67 LOCATE,8
68 PRINT" Leistung P4 berechnet werden: P4 = P1 * (SWV - 1) / (SWV + 1) "
69 LOCATE,8
70 PRINT" "
71 LOCATE,8
72 PRINT" Über die Kabeldämpfung ergibt sich die am Antennenfußpunkt re- "
73 LOCATE,8
74 PRINT" flektierte Leistung P3: P3 = P4 / 10^ (D/10) "
75 LOCATE,8
76 PRINT" "
77 LOCATE,8
78 PRINT" Aus der am Antennenfußpunkt ermittelten Leistung P2 läßt sich nun "
79 LOCATE,8
80 PRINT" auch das reale SWVant an der Antenne berechnen: "
81 LOCATE,8
82 PRINT" SWVant = (P2+P4) / (P2-P4) "
83 LOCATE,8
84 PRINT" "
85 LOCATE,8
86 PRINT" Über den Antennengewinn kann die relative Strahlungsleistung er- "
87 LOCATE,8
88 PRINT" mittelt werden. "
89 LOCATE 25, 55, 0: COLOR 4, 7: PRINT " BERECHNUNG ? (j/n) ";
90 X$ = INKEY$
95 IF X$ = "j" THEN GOTO 105
100 IF X$ = "n" THEN GOTO 410 ELSE 90
105 SCREEN 0: CLS: LOCATE 2, 10: COLOR 15,6
110 PRINT " L E I S T U N G S - U N D S W V - B E R E C H N U N G "
111 LOCATE 25, 57: COLOR 4, 3: PRINT " WEITER ? (j/n) ";
112 X$ = INKEY$
113 IF X$ = "j" THEN GOTO 115
114 IF X$ = "n" THEN GOTO 410 ELSE 112
115 LOCATE 25,1: COLOR,0: PRINT STRING$(80,32);
116 LOCATE 4, 24, 1, 0, 7: COLOR 15,5,9: INPUT " Sendefrequenz (MHz) = ", f$
120 f = VAL(f$)
125 IF f=0 THEN GOSUB 390: COLOR,0:LOCATE 4,44:PRINT STRING$(37,32);:GOTO 116
130 '
135 LOCATE 6, 24: COLOR 15, 2: INPUT " Ausgangsleistung (W) = ", P1$
140 P1 = VAL(P1$)
145 IF P1=0 THEN GOSUB 390: COLOR,0:LOCATE 6,44:PRINT STRING$(37,32);:GOTO 135
150 '
155 LOCATE 8, 24: COLOR 15, 2: INPUT " Stehwellenverhältnis = ", SWV$
160 SWV = VAL(SWV$)
165 IF SWV=0 THEN GOSUB 390: COLOR,0:LOCATE 8,44:PRINT STRING$(37,32);:GOTO 155
170 '
175 LOCATE 10, 24: COLOR 15,2: INPUT " Leitungslänge (m) = ", l$
180 l = VAL(l$)
185 IF l=0 THEN GOSUB 390: COLOR,0:LOCATE 10,44:PRINT STRING$(37,32);:GOTO 175
190 '
195 LOCATE 12,24: COLOR 15,2: INPUT " 30 MHz-Dämpfung/100m = ", A$
200 A = VAL(A$)
205 IF A=0 THEN GOSUB 390: COLOR,0:LOCATE 12,44:PRINT STRING$(37,32);:GOTO 195
210 '
215 Af = A * 2.6^(log(f/30)/1.8) ' Daempfung fuer f bei 100 m
220 D = l * Af / 100 ' Kabeldaempfung in dB
225 P2 = P1 / 10^(D/10) ' Leistung am Antennenfusspunkt in W
230 P4 = P1 * (SWV - 1) / (SWV + 1) ' rueckfliessende Leistung in W
235 P3 = P4 / 10^(D/10)' reflektierte Leistung in W
240 SWVant= (P2+P4) / (P2-P4) ' SWV an der Antenne
245 LOCATE 14, 24: COLOR 15, 6
250 PRINT" Dämpfung / 100 m (dB) =";:PRINT USING"#####.#"; Af
255 LOCATE, 24: PRINT" Kabeldämpfung (dB) =";:PRINT USING"#####.#"; D
260 LOCATE, 24: PRINT" Leistungsverlust (W) =";:PRINT USING"#####.#";(P1-P2)
265 LOCATE, 24: PRINT" Leistung an Antenne (W) =";:PRINT USING"#####.#"; P2
270 LOCATE, 24: PRINT" SWV an Antenne =";:PRINT USING"#####.#"; SWVant
275 IF SWVant < 0 THEN GOSUB 430
280 LOCATE 19, 24
285 PRINT" abzustr. Leistung (W) =";:PRINT USING"#####.#"; P2-P3;
290 LOCATE 20, 24: COLOR 15,6: INPUT" Antennengewinn (dB) = ", G$
295 G = VAL(G$)
300 IF G=0 THEN GOSUB 390: COLOR,0: LOCATE 20,44:PRINT STRING$(37,32);:GOTO 290
305 '
310 LOCATE 22, 24
315 PRINT" relative Leistung (W) =";:PRINT USING"#####.#"; (P2-P3)*10^(G/10)
320 IF P3 < 0.1 THEN 350
325 LOCATE 23, 24: PRINT" reflekt. Leistung (W) =";:PRINT USING"#####.#"; P3
330 LOCATE 24, 24: PRINT" rückfl. Leistung (W) =";:PRINT USING"#####.#"; P4;
350 LOCATE 25, 58,0: COLOR 4, 3: PRINT " neue Berechnung j/n ";
360 X$ = INKEY$
370 IF X$ = "j" THEN GOTO 405
380 IF X$ = "n" THEN GOTO 410 ELSE 360
390 PLAY "C18": PLAY "C18": PLAY "C9": PLAY "C9": PLAY "C18": PLAY "C18"
400 RETURN
405 SCREEN 0: COLOR, 0: CLS: CLEAR: GOTO 115
410 PLAY "L10": PLAY "N20": PLAY "N20": PLAY "N20": PLAY "L3": PLAY "N15"
420 WIDTH "SCRN:",40: SYSTEM
430 LOCATE, 24: PRINT" Stehwellenverhältnis = "STRING$(1,236)" ";
440 RETURN
Read previous mail | Read next mail
| |
