| |
DB1ZF > MSX 16.06.95 11:35l 49 Lines 1617 Bytes #-10859 (0) @ WW
BID : 16650BDB0GV
Read: DH1FBK OE5LPO OK1IKE DF2SKE GUEST
Subj: WECKER.BAS
Path: DB0AAB<DB0KCP<DB0CRL<DB0RBS<DB0AIS<DB0GV
Sent: 950616/0808z @DB0GV.#HES.DEU.EU [Maintal-Frank4t JO40KD 438.025 SYSOP: DF
de DB1ZF @ DB0GV.#HES.DEU.EU (Kurt)
to MSX @ WW
10 REM Kurzzeitwecker von Horst Lauterwald, 60489 Frankfurt im Mai 1994
15 REM published im MSX-Contakt 2/95
20 REM written by DB1ZF
100 CLS:SCREEN1:COLOR 15,4,15:KEY OFF:DEFINT A-Z:PRINT:PRINT:PRINT:LOCATE,,0
110 PRINT TAB(6);"Kurzzeitwecker"
120 PRINT TAB(6);STRING$(14,"_")
130 PRINT:PRINT TAB(2);"Unterbrechen mit <STOP>"
140 PRINT:PRINT TAB(2);"Ende mit <CTRL> + <STOP>"
150 PRINT:PRINT TAB(9);"Eingabe:"
160 PRINT:PRINT:INPUT" Minuten - von 0 bis 99";MN$
170 IF MN$<"0" OR MN$>"99" THEN 450
180 MN=VAL(MN$):IF MN>99 THEN 450
190 PRINT:PRINT:INPUT"Sekunden - von 0 bis 59";SC$
200 IF SC$<"0" OR SC$>"99" THEN CLS:GOTO 450
210 SC=VAL(SC$):CLS:IF SC>59 THEN 450
220 TIME=0
230 T=INT(TIME/3000*60)
240 IF T<>S THEN BEEP:SC=SC-1:S=T
245 LOCATE 6,2:PRINT "Kurzzeitwecker"
250 LOCATE 8,7:PRINT STRING$(10,"_")
260 FOR I=8 TO 14
270 LOCATE 8,I:PRINT"_"
280 NEXT I
290 FOR I=8 TO 14
300 LOCATE 17,I:PRINT"_"
305 LOCATE 13,22:PRINT"(c)H.Lauterwald"
310 NEXT I
320 LOCATE 8,15:PRINT STRING$(10,"_")
330 LOCATE 10,11:PRINT USING "##";MN;:PRINT ":";:PRINT USING "##";SC
340 IF SC=0 THEN MN=MN-1:SC=60
350 IF MN=-1 THEN 360 ELSE GOTO 230
360 FOR I=8 TO 50:FOR J=0 TO 80:NEXT J:SOUND 6,9:SOUND 7,56:SOUND 8,16:SOUND 12,22:SOUND 13,8:NEXT I
370 COLOR 4,4,15
380 ON STOP GOSUB 440:STOP ON
385 LOCATE 8,5:PRINT"DB1ZF-1995"
390 FOR I=8 TO 200:NEXT I
400 COLOR 15,4,15
410 FOR I=0 TO 400:NEXT I
420 SOUND 6,10:SOUND 7,55:SOUND 8,16:SOUND 12,4:SOUND 13,9
430 GOTO 370
440 COLOR 15,4,15:SCREEN0:END
450 CLS:LOCATE 7,10:PRINT"Falscheingabe!"
460 FOR I=0 TO 800:NEXT I
470 GOTO 100
Read previous mail | Read next mail
| |
