| |
DL1MDY > CASIO 06.07.98 01:24l 180 Lines 2457 Bytes #999 (999) @ ALLE
BID : 578DB0ZKA01H
Read: DG1HUA DG2NBN GUEST
Subj: TRANSFPB.PRG
Path: DB0MAK<DB0ERF<DB0MW<DB0AIS<DB0GV<DB0CZ<DB0KFB<DB0ZKA
Sent: 980705/2125z @:DB0ZKA.#BAY.DEU.EU [Augsburg JN58ki] BCM1.39tb
From: DL1MDY @ DB0ZKA.#BAY.DEU.EU (Pius)
To: CASIO @ ALLE
X-Info: No login password
X-BID: 578DB0ZKA01H
'c-sng 5/88
'transfer.v3
10 CLS:CLEAR
20 ON ERROR GOTO 800
30 PAR$="7,N,8,1,N,N,N,B,N"
40 PRINT REV " * PB 1000 DATEN - TRANSFER *";
50 LOCATE 8,1:PRINT" 1: SENDEN "
60 LOCATE 8,2:PRINT" 2: EMPFANG "
70 LOCATE 8,3:PRINT" 3: ENDE " ;NORM;
80 a=ASC(INKEY$)
90 IF a=245 OR a=246 OR a=49 THEN 150
100 IF a=249 OR a=250 OR a=50 THEN 490
110 IF a=253 OR a=254 OR a=51 THEN 130
120 GOTO 80
130 CLS:PRINT:PRINT TAB(12) "E N D E"
140 END
150 'SENDEN
160 CLS
170 PRINT:INPUT " Wieviele seq. Dateien werden gesendet :",n
180 IF n<1 THEN n=1
190 DIM SQ$(n)
200 CLS
210 FOR i=1 TO n
220 PRINT " ";i;":";:INPUT " Datei-Name :",SQ$(i)
230 NEXT i
240 FOR i=1 TO n
250 OPEN SQ$(i) FOR INPUT AS#2
260 CLS
270 IF i>1 THEN GOTO 330
280 PRINT " Parameter - Einstellung :"
290 PRINT PAR$
300 PRINT""," [EXE] -> SENDE - START !";
310 LOCATE 0,1:INPUT"",PAR$
320 PAR$=LEFT$(PAR$,17)
330 OPEN"COM0:"+PAR$ FOR OUTPUT AS#1
340 CLS:BEEP 1
350 LINE INPUT #2,A$
360 PRINT #1,A$
370 PRINT A$
380 IF EOF(2)=0 THEN 350
390 A$=CHR$(13)
400 PRINT#1,A$
410 CLOSE
420 CLS:BEEP 1:PRINT TAB(16-LEN(SQ$(i))/2) REV SQ$(i)
430 PRINT NORM TAB(8)"ENDE DES SENDENS"
440 FOR j=1 TO 365:NEXT j
450 NEXT i
460 IF i>1 THEN GOTO 10
470 PRINT:PRINT TAB(8)" [EXE] -> MENUE";
480 IF INKEY$=CHR$(13) THEN 10 ELSE 480
490 'EMPFANG
500 CLS
510 PRINT:INPUT" Wieviele Dateien werden empfangen :",n
520 IF n<1 THEN n=1
530 DIM SQ$(n)
540 CLS
550 FOR i=1 TO n
560 PRINT " ";i;":";:INPUT" Datei - Name :",SQ$(i)
570 NEXT i
580 FOR i=1 TO n
590 OPEN SQ$(i) FOR OUTPUT AS#1
600 CLS
610 IF i>1 THEN GOTO 660
620 PRINT" Parameter-Einstellung:"
630 PRINT PAR$
640 PRINT""," [EXE] -> EMPFANG - START !";
650 LOCATE 0,1:INPUT"",PAR$
660 OPEN"COM0:"+PAR$ FOR INPUT AS#2
670 CLS:BEEP 1
680 LINE INPUT#2,A$
690 IF LEN(A$)=0 THEN 730
700 PRINT#1,A$
710 PRINT A$
720 GOTO 680
730 CLS:CLOSE:BEEP 1
740 NEXT i
750 IF i>1 THEN GOTO 10
760 PRINT TAB(16-LEN(SQ$(i))/2) REV SQ$(i)
770 PRINT NORM TAB(8)"ENDE DES EMPFANGS"
780 PRINT:PRINT TAB(8)" [EXE] -> MENUE";
790 IF INKEY$=CHR$(13) THEN 10 ELSE 790
800 ' ERROR
810 CLS:BEEP 1
820 PRINT TAB(10)"F E H L E R !"
830 PRINT TAB(3)"ERROR ";ERR;"in Zeile ";ERL
840 IF ERR=10 THEN PRINT" DATEI nicht gespeichert!"
850 ss$=INPUT$(1)
860 GOTO 10
Read previous mail | Read next mail
| |
