| |
DL1MDY > CASIO 06.07.98 01:22l 94 Lines 2008 Bytes #999 (999) @ ALLE
BID : 578DB0ZKA01E
Read: DG1HUA DG2NBN GUEST
Subj: LOC-ENTF.PRG
Path: DB0MAK<DB0ERF<DB0MW<DB0AIS<DB0GV<DB0CZ<DB0KFB<DB0ZKA
Sent: 980705/2116z @:DB0ZKA.#BAY.DEU.EU [Augsburg JN58ki] BCM1.39tb
From: DL1MDY @ DB0ZKA.#BAY.DEU.EU (Pius)
To: CASIO @ ALLE
X-Info: No login password
X-BID: 578DB0ZKA01E
10 REM ENTFERNUNGS BERECHNUNG MIT EU & WW LOCATOR
20 IF XYZ = 1 THEN 90
30 DIM H(20):FOR I=1 TO 20:READ H(I):NEXT
40 ANGLE 1:K=PI/180:L=180/PI:M=PI/2
50 INPUT"EIGENEN LOCATOR EINGEBEN";A$
60 IF LEN(A$)<5 OR LEN(A$)>6 THEN PRINT"EINGABEFEHLER !":GOTO50
70 EL$=A$:GOSUB 120
80 X=U:Y=V:XYZ=1
90 GOSUB 100:GOSUB 350:GOTO 90
100 INPUT"LOCATOR DER GEGENSTATION";A$
110 IF A$=EL$ THEN T1=0:Q=0: GOSUB 360 : GOTO 100
120 IF LEN(A$)=5 THEN GOSUB 230: RETURN
130 IF LEN(A$)=6 THEN GOSUB 300: RETURN
140 PRINT"EINGABEFEHLER !!":GOTO 100
150 IF Z<0 THEN Q=360-Q
160 RETURN
170 T=(COS(Z)*COS(U)*COS(X))+(SIN(U)*SIN(X))
180 T=(-ATN(T/SQR(1-T*T)))+M:T1=T*40009/(2*PI)
190 Q=(SIN(U)-(SIN(X)*COS(T)))/(COS(X)*SIN(T))
200 IF Q>0.999999 THEN Q=0:RETURN
210 IF Q<-0.999999 THEN Q=180:RETURN
220 Q=(-ATN(Q/SQR(1-Q^2)))+M:Q=Q*L:RETURN
230 S1$=LEFT$(A$,2):S2$=MID$(A$,2,2):S3$=MID$(A$,3,1):S4$=MID$(A$,4,1)
240 S5$=MID$(A$,5,2):B=ASC(S1$)-65:C=ASC(S2$)-64
250 D=VAL(S3$):E=VAL(S4$):F=ASC(S5$)-64:IF B>21 THEN B=B-26
260 IF C>23 THEN C=C-26
270 IF E=0 THEN E=10:D=D-1
280 U=K*(40+C-(D/8)-(H(F+10)/24)-0.020833)
290 V=K*((2*B)+(E/5)+(H(F)/15)-0.169):RETURN
300 B1=ASC(LEFT$(A$,2)):B2=ASC(MID$(A$,2,2)):Z1=VAL(MID$(A$,3,1))
310 Z2=VAL(MID$(A$,4,1)):B3=ASC(MID$(A$,5,2)):B4=ASC(MID$(A$,6,2))
320 V=K*((B1-65)*20-180+(Z1*2)+(B3-65)/12+1/24)
330 U=K*((B2-65)*10-90+Z2+(B4-65)/24+1/48)
340 RETURN
350 Z=V-Y:GOSUB 170:GOSUB 150
360 PRINT"QRB =";INT(T1+0.5);"km";" QTF =";INT(Q+0.5);"grad"
370 DS=INT(T1+0.5):SU=DS+SU:AN=AN+1:IF DS>WV THEN WV=DS
380 DU = INT(SU/AN+0.5)
390 PRINT"SUMME =";SU;"km ";"ODX =";WV;"km"
400 PRINT"ANZAHL = ";AN;" MITEL = ";DU;"km"
410 RETURN
420 DATA 1,2,2,2,1,0,0,0,1,1,0,0,1,2,2,2,1,0,1,1
430 'QELLE : DUBUS 1/85 SEITE 18ZEILE 130,170,180, NACH DL9MCK
440 'DIVERSE ANPASSUNG VON DL5MCG
450 'ZEILE 60,90,210,220,270,280,320,330,340,350 NACH DL1MDY FUR PB 1000
Read previous mail | Read next mail
| |
