| |
DL1MDY > CASIO 06.07.98 00:11l 146 Lines 2641 Bytes #999 (999) @ ALLE
BID : 578DB0ZKA01C
Read: DG1HUA DG2NBN GUEST
Subj: DIRECTOR.PRG
Path: DB0MAK<DB0RGB<DB0LAN<DB0ABH<DB0ZKA
Sent: 980705/2110z @:DB0ZKA.#BAY.DEU.EU [Augsburg JN58ki] BCM1.39tb
From: DL1MDY @ DB0ZKA.#BAY.DEU.EU (Pius)
To: CASIO @ ALLE
X-Info: No login password
X-BID: 578DB0ZKA01C
10 REM **** DIRECTORY ****
20 REM * (C) H.BOEHLING 22.03.88 *
25 'Programmstand : 16.11.90
30 'Programmlaenge : 2282 Bytes
35 CLS:CLEAR:W$="N"
40 STAD=(PEEK(&H694B)+PEEK(&H694C)*256)-32
50 PRINTREV" *** DIRECTORY *** ";NORM;
60 IF PEEK(&H0C04)=255 THEN 90:REM KEIN INTERFACE VORHANDEN
70 PRINT"Druckerausgabe (J/N bzw. EXE) ?";:W$=INPUT$(1):PRINT W$
80 IF W$="j" OR W$="y" OR W$="Y" THEN W$="J":PRINT W$
90 PRINT" Bitte LEERTASTE druecken !"
95 PRINTREV" FILENAME.EXT LAENGE PASSWORT ";NORM;
100 IF W$="J" THEN LPRINT " FILENAME.EXT LAENGE PASS Gespeichert Maschinenprogramme"
110 IF W$="J" THEN LPRINT "WORT von bis Beginn Ende Start ":LPRINT
120 REM == STATUS ============
130 ST$="?":ST=PEEK(STAD)
140 IF ST=0 THEN ST$=" "
150 IF ST=1 THEN ST$="*"
160 IF ST=2 THEN ST$="#"
170 REM == START/ENDADRESSE/LAENGE ==
180 PST=PEEK(STAD+1)+PEEK(STAD+2)*256
190 PST$=" &H"+HEX$(PST)
200 PEND=PEEK(STAD+3)+PEEK(STAD+4)*256
210 PEND$=" &H"+HEX$(PEND)
220 LAENGE=PEND-PST-1:SUMM=SUMM+LAENGE
230 REM == DATEITYP ==
240 TYP$="?":TYP=PEEK(STAD+5)
250 IF TYP=16 THEN TYP$="B"
260 IF TYP=13 THEN TYP$="M"
270 IF TYP=36 THEN TYP$="S"
280 REM == PROGRAMMNAME ==
290 NAME$=""
300 FOR NAME=STAD+6 TO STAD+16
310 NAME$=NAME$+CHR$(PEEK(NAME))
320 NEXT NAME
330 NAME$=LEFT$(NAME$,8)+"."+RIGHT$(NAME$,3)
340 REM == BASICPROGRAMM ==
350 REM ==PASSWORT ==
360 PASW$=" "
370 IF TYP$<>"B" THEN 450:REM KEIN BASIC
380 IF PEEK(STAD+17)=255 THEN 510: REM KEIN PASSWORT
390 PASW$=""
400 FOR PASW=STAD+17 TO STAD+24
410 PA$=CHR$(255-PEEK(PASW))
420 IF ASC(PA$)<32 THEN PA$=" "
430 PASW$=PASW$+PA$
440 NEXT PASW
450 REM == MASCHINENPROGRAMM ==
460 REM == BEGINN/ENDE/START ==
470 IF TYP$<>"M" THEN 510: REM KEIN MASCHINENPROGRAMM
480 BEG$=" &H"+HEX$(PEEK(STAD+25)+PEEK(STAD+26)*256)
490 EN$=" &H"+HEX$(PEEK(STAD+27)+PEEK(STAD+28)*256)
500 STA$=" &H"+HEX$(PEEK(STAD+29)+PEEK(STAD+30)*256)
510 REM == AUSGABE ==
520 PRINT NAME$;ST$;TYP$;" ";
530 PRINT USING"#####";LAENGE;
540 PRINT" ";PASW$
550 IF TYP$="M" THEN PRINT BEG$;EN$;STA$
560 REM == DRUCKER ==
570 IF W$<>"J" THEN 620
580 LPRINT NAME$;ST$;TYP$;" ";
590 LPRINT USING"#####";LAENGE;
600 LPRINT" ";PASW$;" ";PST$;PEND$;" ";
610 IF TYP$="M" THEN LPRINT BEG$;EN$;STA$ ELSE LPRINT
620 REM == ENDE ? ==
630 IF W$<>"J" AND INKEY$="" THEN 630
640 STAD=STAD-32
650 IF PEEK(STAD+1)+PEEK(STAD+2)*256=PEND THEN 120
660 PRINT SUMM;"Byte(s) belegt !"
670 IF W$="J" THEN LPRINT:LPRINT SUMM;"Byte(s) belegt !"
680 END
Read previous mail | Read next mail
| |
